<xsl:template name="generateAppInfo">
  <appInfo>
    <application ident="TEI_fromDOCX" version="2.12.0">
      <label>DOCX to TEI</label>
    </application>
    <xsl:if test="xpath:doc-available(concat($word-directory,'/docProps/custom.xml'))">
      <xsl:for-each select="xpath:doc(concat($word-directory,'/docProps/custom.xml'))/prop:Properties">
        <xsl:for-each select="prop:property">
          <xsl:choose>
            <xsl:when test="@name='TEI_fromDOCX'"/>
            <xsl:when test="contains(@name,'TEI')">
              <application ident="{@name}" version="{.}">
                <label>
                  <xsl:value-of select="@name"/>
                </label>
              </application>
            </xsl:when>
          </xsl:choose>
        </xsl:for-each>
        <application ident="WordTemplate" version="{prop:property[@name='WordTemplate']}">
          <label>Word template file</label>
          <ptr target="{prop:property[@name='WordTemplateURI']}"/>
        </application>
      </xsl:for-each>
    </xsl:if>
  </appInfo>
</xsl:template>

<xsl:template name="getDocTitle">
  <xsl:for-each select="document(concat($word-directory, '/docProps/core.xml'),/)">
    <xsl:value-of select="cp:coreProperties/dc:title"/>
  </xsl:for-each>
</xsl:template>

<xsl:template name="getDocAuthor">
  <xsl:for-each select="document(concat($word-directory, '/docProps/core.xml'),/)">
    <xsl:value-of select="cp:coreProperties/dc:creator"/>
  </xsl:for-each>
</xsl:template>

<xsl:template name="getDocDate">
  <xsl:for-each select="document(concat($word-directory, '/docProps/core.xml'),/)">
    <xsl:value-of select="substring-before(cp:coreProperties/dcterms:created,'T')"/>
  </xsl:for-each>
</xsl:template>

<xsl:template name="identifyChange">
  <xsl:param name="who"/>
  <xsl:attribute name="resp">
    <xsl:text>#</xsl:text>
    <xsl:value-of select="translate($who,' ','_')"/>
  </xsl:attribute>
</xsl:template>