<xsl:template match="*" mode="innertext">
  <xsl:apply-templates select="."/>
</xsl:template>

<xsl:template match="*" mode="paging">
  <xsl:choose>
    <xsl:when test="self::tei:divGen[@type='summary']">
      <xsl:call-template name="summaryToc"/>
    </xsl:when>
    <xsl:when test="self::tei:divGen">
      <xsl:apply-templates select="."/>
    </xsl:when>
    <xsl:when test="starts-with(local-name(),'div')">
      <xsl:if test="not(preceding-sibling::tei:*) or preceding-sibling::tei:titlePage">
        <h2>
          <xsl:apply-templates mode="xref" select="."/>
          <xsl:call-template name="sectionHeadHook"/>
        </h2>
        <xsl:if test="$topNavigationPanel='true'">
          <xsl:call-template name="xrefpanel">
            <xsl:with-param name="homepage" select="concat($masterFile,$standardSuffix)"/>
            <xsl:with-param name="mode" select="local-name(.)"/>
          </xsl:call-template>
        </xsl:if>
        <xsl:call-template name="doDivBody"/>
        <xsl:if test="$bottomNavigationPanel='true'">
          <xsl:call-template name="xrefpanel">
            <xsl:with-param name="homepage" select="concat($masterFile,$standardSuffix)"/>
            <xsl:with-param name="mode" select="local-name(.)"/>
          </xsl:call-template>
        </xsl:if>
      </xsl:if>
    </xsl:when>
    <xsl:when test="local-name(..)='front'">
      <xsl:apply-templates select="."/>
      <xsl:apply-templates mode="paging" select="following-sibling::tei:*[1]"/>
      <xsl:apply-templates mode="paging" select="../../tei:body/tei:*[1]"/>
    </xsl:when>
    <xsl:otherwise>
      <xsl:apply-templates select="."/>
      <xsl:apply-templates mode="paging" select="following-sibling::tei:*[1]"/>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

<xsl:template match="/">
  <xsl:if test="contains($processor,'Clark')">
    <xsl:message terminate="yes">XT is not supported by the TEI stylesheets,
        as it does not implement the "key" function</xsl:message>
  </xsl:if>
  <xsl:call-template name="processTEI"/>
</xsl:template>

<xsl:template name="processTEI">
  <xsl:choose>
    <!-- there are various choices of how to proceed, driven by
	    
	    $pageLayout: Simple, CSS, Table, Frames
	    
	    $STDOUT: true or false
	    
	    $splitLevel: -1 to 3
	    
	    $requestedID: requests a particular page
       -->
    <!-- we are making a composite layout and there is a TEI or teiCorpus element -->
    <xsl:when test="($pageLayout = 'CSS' or $pageLayout = 'Table') and (tei:TEI or tei:teiCorpus)">
      <xsl:if test="$verbose='true'">
        <xsl:message>case 1: pageLayout
          <xsl:value-of select="$pageLayout"/>
        </xsl:message>
      </xsl:if>
      <xsl:for-each select="tei:TEI|tei:teiCorpus">
        <xsl:call-template name="doPageTable">
          <xsl:with-param name="currentID" select="$requestedID"/>
        </xsl:call-template>
      </xsl:for-each>
      <xsl:if test="$STDOUT='false'">
        <xsl:call-template name="doDivs"/>
      </xsl:if>
    </xsl:when>
    <!-- we are making a frame-based system -->
    <xsl:when test="$pageLayout='Frames'">
      <xsl:if test="$verbose='true'">
        <xsl:message>case 2: pageLayout
          <xsl:value-of select="$pageLayout"/>
        </xsl:message>
      </xsl:if>
      <xsl:call-template name="doFrames"/>
    </xsl:when>
    <!-- we have been asked for a particular section of the document -->
    <xsl:when test="not($requestedID='')">
      <xsl:if test="$verbose='true'">
        <xsl:message>case 3: ID
          <xsl:value-of select="$requestedID"/>, pageLayout
          <xsl:value-of select="$pageLayout"/>
        </xsl:message>
      </xsl:if>
      <xsl:choose>
        <xsl:when test="$requestedID='frametoc___'">
          <xsl:call-template name="writeFrameToc"/>
        </xsl:when>
        <xsl:when test="$requestedID='prelim___'">
          <xsl:apply-templates/>
        </xsl:when>
        <xsl:when test="count(key('IDS',$requestedID))>0">
          <xsl:for-each select="key('IDS',$requestedID)">
            <xsl:call-template name="writeDiv"/>
          </xsl:for-each>
        </xsl:when>
        <xsl:otherwise>
          <!-- the passed ID is a pseudo-XPath expression
		  which starts below TEI/text.
		  The real XPath syntax is changed to avoid problems
	     -->
          <xsl:apply-templates mode="xpath" select="tei:TEI/tei:text">
            <xsl:with-param name="xpath" select="$requestedID"/>
          </xsl:apply-templates>
        </xsl:otherwise>
      </xsl:choose>
    </xsl:when>
    <!-- we want HTML to just splurge out-->
    <xsl:when test="$STDOUT='true'">
      <xsl:if test="$verbose='true'">
        <xsl:message>case 4: write to stdout, pageLayout
          <xsl:value-of select="$pageLayout"/>
        </xsl:message>
      </xsl:if>
      <xsl:apply-templates/>
    </xsl:when>
    <!-- we want the document split up into separate files -->
    <xsl:when test="tei:TEI or tei:teiCorpus and number($splitLevel)>-1">
      <xsl:if test="$verbose='true'">
        <xsl:message>case 5: split output,
          <xsl:value-of select="$splitLevel"/>pageLayout
          <xsl:value-of select="$pageLayout"/>
        </xsl:message>
      </xsl:if>
      <xsl:apply-templates mode="split"/>
    </xsl:when>
    <!-- we want the whole document, in an output file -->
    <xsl:otherwise>
      <xsl:if test="$verbose='true'">
        <xsl:message>case 6: one document, pageLayout
          <xsl:value-of select="$pageLayout"/>
        </xsl:message>
      </xsl:if>
      <xsl:choose>
        <xsl:when test="$masterFile='' or $STDOUT='true'">
          <xsl:apply-templates/>
        </xsl:when>
        <xsl:otherwise>
          <xsl:variable name="outName">
            <xsl:call-template name="outputChunkName">
              <xsl:with-param name="ident">
                <xsl:value-of select="$masterFile"/>
              </xsl:with-param>
            </xsl:call-template>
          </xsl:variable>
          <xsl:if test="$verbose='true'">
            <xsl:message>Opening file
              <xsl:value-of select="$outName"/>
            </xsl:message>
          </xsl:if>
          <xsl:result-document doctype-public="{$doctypePublic}" doctype-system="{$doctypeSystem}" encoding="{$outputEncoding}" href="{$outName}" method="{$outputMethod}">
            <xsl:apply-templates/>
          </xsl:result-document>
          <xsl:if test="$verbose='true'">
            <xsl:message>Closing file
              <xsl:value-of select="$outName"/>
            </xsl:message>
          </xsl:if>
        </xsl:otherwise>
      </xsl:choose>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

<xsl:template match="processing-instruction()[name()='xmltex']">
  <xsl:value-of select="."/>
</xsl:template>

<xsl:template match="tei:*" mode="generateNextLink">
  <span class="nextLink">
    <xsl:text> </xsl:text>
    <xsl:call-template name="i18n">
      <xsl:with-param name="word">nextWord</xsl:with-param>
    </xsl:call-template>
    <xsl:call-template name="navInterSep"/>
  </span>
  <a class="navigation">
    <xsl:attribute name="href">
      <xsl:apply-templates mode="generateLink" select="."/>
    </xsl:attribute>
    <xsl:call-template name="headerLink">
      <xsl:with-param name="minimal" select="$minimalCrossRef"/>
    </xsl:call-template>
  </a>
</xsl:template>

<xsl:template match="tei:*" mode="generatePreviousLink">
  <span class="previousLink">
    <xsl:text> </xsl:text>
    <xsl:call-template name="i18n">
      <xsl:with-param name="word">previousWord</xsl:with-param>
    </xsl:call-template>
    <xsl:call-template name="navInterSep"/>
  </span>
  <a class="navigation">
    <xsl:attribute name="href">
      <xsl:apply-templates mode="generateLink" select="."/>
    </xsl:attribute>
    <xsl:call-template name="headerLink">
      <xsl:with-param name="minimal" select="$minimalCrossRef"/>
    </xsl:call-template>
  </a>
</xsl:template>

<xsl:template match="tei:*" mode="xpath">
  <xsl:param name="xpath"/>
  <xsl:param name="action"/>
  <xsl:choose>
    <!-- if there is a path -->
    <xsl:when test="$xpath">
      <!-- step is the part before the '_' (if there is one) -->
      <xsl:variable name="step">
        <xsl:choose>
          <xsl:when test="contains($xpath, '_')">
            <xsl:value-of select="substring-before($xpath, '_')"/>
          </xsl:when>
          <xsl:otherwise>
            <xsl:value-of select="$xpath"/>
          </xsl:otherwise>
        </xsl:choose>
      </xsl:variable>
      <!-- the child's name is the part before the '.' -->
      <xsl:variable name="childName" select="substring-before($step, '.')"/>
      <!-- and its index is the part after '.' -->
      <xsl:variable name="childIndex" select="substring-after($step, '.')"/>
      <!-- so apply templates to that child, passing in the $xpath
	     left after the first step -->
      <xsl:apply-templates mode="xpath" select="*[name() = $childName]          [number($childIndex)]">
        <xsl:with-param name="xpath" select="substring-after($xpath, '_')"/>
        <xsl:with-param name="action" select="$action"/>
      </xsl:apply-templates>
    </xsl:when>
    <!-- if there's no path left, then this is the element we want -->
    <xsl:otherwise>
      <xsl:choose>
        <xsl:when test="$action='header'">
          <xsl:apply-templates mode="xref" select="."/>
        </xsl:when>
        <xsl:when test="$action='notes'">
          <xsl:call-template name="printNotes"/>
        </xsl:when>
        <xsl:when test="$action='toclist'">
          <xsl:call-template name="linkListContents">
            <xsl:with-param name="style" select="'toclist'"/>
          </xsl:call-template>
        </xsl:when>
        <xsl:when test="starts-with(local-name(),'div') and      $pageLayout='Table'      or      $pageLayout='CSS'">
          <h2>
            <xsl:apply-templates mode="xref" select="."/>
            <xsl:call-template name="sectionHeadHook"/>
          </h2>
          <xsl:if test="$topNavigationPanel='true'">
            <xsl:call-template name="xrefpanel">
              <xsl:with-param name="homepage" select="concat($masterFile,$standardSuffix)"/>
              <xsl:with-param name="mode" select="local-name(.)"/>
            </xsl:call-template>
          </xsl:if>
          <xsl:call-template name="doDivBody"/>
          <xsl:if test="$bottomNavigationPanel='true'">
            <xsl:call-template name="xrefpanel">
              <xsl:with-param name="homepage" select="concat($masterFile,$standardSuffix)"/>
              <xsl:with-param name="mode" select="local-name(.)"/>
            </xsl:call-template>
          </xsl:if>
        </xsl:when>
        <xsl:when test="self::tei:divGen[@type='summary']">
          <xsl:call-template name="summaryToc"/>
        </xsl:when>
        <xsl:otherwise>
          <html>
            <xsl:call-template name="addLangAtt"/>
            <xsl:call-template name="htmlFileTop"/>
            <body id="TOP">
              <xsl:call-template name="bodyHook"/>
              <xsl:call-template name="bodyJavascriptHook"/>
              <div class="stdheader">
                <xsl:call-template name="stdheader">
                  <xsl:with-param name="title">
                    <xsl:call-template name="generateTitle"/>
                  </xsl:with-param>
                </xsl:call-template>
              </div>
              <h2>
                <xsl:apply-templates mode="xref" select="."/>
                <xsl:call-template name="sectionHeadHook"/>
              </h2>
              <xsl:apply-templates/>
              <xsl:call-template name="printNotes"/>
              <xsl:call-template name="htmlFileBottom"/>
              <xsl:call-template name="bodyEndHook"/>
            </body>
          </html>
        </xsl:otherwise>
      </xsl:choose>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

<xsl:template match="tei:TEI">
  <xsl:call-template name="teiStartHook"/>
  <xsl:if test="$verbose='true'">
    <xsl:message>TEI HTML in single document mode</xsl:message>
  </xsl:if>
  <html>
    <xsl:call-template name="addLangAtt"/>
    <head>
      <xsl:variable name="pagetitle">
        <xsl:call-template name="generateTitle"/>
      </xsl:variable>
      <title>
        <xsl:value-of select="$pagetitle"/>
      </title>
      <xsl:call-template name="headHook"/>
      <xsl:call-template name="metaHTML">
        <xsl:with-param name="title" select="$pagetitle"/>
      </xsl:call-template>
      <xsl:call-template name="includeCSS"/>
      <xsl:call-template name="cssHook"/>
      <xsl:call-template name="includeJavascript"/>
      <xsl:call-template name="javascriptHook"/>
    </head>
    <body class="simple" id="TOP">
      <xsl:call-template name="bodyHook"/>
      <xsl:call-template name="bodyJavascriptHook"/>
      <xsl:if test="not(tei:text/tei:front/tei:titlePage)">
        <div class="stdheader">
          <xsl:call-template name="stdheader">
            <xsl:with-param name="title">
              <xsl:call-template name="generateTitle"/>
            </xsl:with-param>
          </xsl:call-template>
        </div>
      </xsl:if>
      <xsl:call-template name="startHook"/>
      <xsl:call-template name="simpleBody"/>
      <xsl:call-template name="stdfooter"/>
      <xsl:call-template name="bodyEndHook"/>
    </body>
  </html>
  <xsl:if test="$verbose='true'">
    <xsl:message>TEI HTML: run end hook template teiEndHook</xsl:message>
  </xsl:if>
  <xsl:call-template name="teiEndHook"/>
</xsl:template>

<xsl:template match="tei:TEI" mode="split">
  <xsl:variable name="BaseFile">
    <xsl:value-of select="$masterFile"/>
    <xsl:call-template name="addCorpusID"/>
  </xsl:variable>
  <xsl:if test="$verbose='true'">
    <xsl:message>TEI HTML: run start hook template teiStartHook</xsl:message>
  </xsl:if>
  <xsl:call-template name="teiStartHook"/>
  <xsl:if test="$verbose='true'">
    <xsl:message>TEI HTML in splitting mode, base file is
      <xsl:value-of select="$BaseFile"/>
    </xsl:message>
  </xsl:if>
  <xsl:variable name="outName">
    <xsl:call-template name="outputChunkName">
      <xsl:with-param name="ident">
        <xsl:choose>
          <xsl:when test="parent::tei:teiCorpus">
            <xsl:apply-templates select="." mode="ident"/>
          </xsl:when>
          <xsl:otherwise>
            <xsl:value-of select="$BaseFile"/>
          </xsl:otherwise>
        </xsl:choose>
      </xsl:with-param>
    </xsl:call-template>
  </xsl:variable>
  <xsl:if test="$verbose='true'">
    <xsl:message>Opening file
      <xsl:value-of select="$outName"/>
    </xsl:message>
  </xsl:if>
  <xsl:result-document doctype-public="{$doctypePublic}" doctype-system="{$doctypeSystem}" encoding="{$outputEncoding}" href="{$outName}" method="{$outputMethod}">
    <xsl:call-template name="pageLayoutSimple"/>
  </xsl:result-document>
  <xsl:if test="$verbose='true'">
    <xsl:message>Closing file
      <xsl:value-of select="$outName"/>
    </xsl:message>
  </xsl:if>
  <xsl:if test="$verbose='true'">
    <xsl:message>TEI HTML: run end hook template teiEndHook</xsl:message>
  </xsl:if>
  <xsl:call-template name="teiEndHook"/>
</xsl:template>

<xsl:template match="tei:front|tei:body|tei:back" mode="split">
  <xsl:message>Split
    <xsl:value-of select="name(.)"/>
  </xsl:message>
  <xsl:for-each select="*">
    <xsl:choose>
      <xsl:when test="starts-with(local-name(.),'div')">
        <xsl:apply-templates mode="split" select="."/>
      </xsl:when>
      <xsl:otherwise>
        <xsl:apply-templates select="."/>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:for-each>
</xsl:template>

<xsl:template match="tei:body" mode="inner">
  <xsl:apply-templates/>
</xsl:template>

<xsl:template match="tei:closer">
  <xsl:choose>
    <xsl:when test="tei:signed">
      <div class="closer">
        <xsl:apply-templates/>
      </div>
    </xsl:when>
    <xsl:when test="tei:p">
      <blockquote class="closer">
        <xsl:apply-templates/>
      </blockquote>
    </xsl:when>
    <xsl:otherwise>
      <blockquote class="closer">
        <p>
          <xsl:apply-templates/>
        </p>
      </blockquote>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

<xsl:template match="tei:dateline">
  <span class="dateline">
    <xsl:apply-templates/>
  </span>
</xsl:template>

<xsl:template match="tei:divGen[@type='actions']">
  <h3>Actions arising</h3>
  <dl>
    <xsl:for-each select="/tei:TEI/tei:text//tei:note[@type='action']">
      <dt>
        <b>
          <xsl:number count="tei:note[@type='action']" level="any"/>
        </b>
      </dt>
      <dd>
        <xsl:apply-templates/>
      </dd>
    </xsl:for-each>
  </dl>
</xsl:template>

<xsl:template match="tei:divGen[@type='toc']">
  <h2>
    <xsl:call-template name="i18n">
      <xsl:with-param name="word">tocWords</xsl:with-param>
    </xsl:call-template>
  </h2>
  <xsl:call-template name="mainTOC"/>
</xsl:template>

<xsl:template match="tei:div1[@type='letter']|tei:div[@type='letter']">
  <div class="letter">
    <xsl:apply-templates/>
  </div>
</xsl:template>

<xsl:template match="tei:div[@type='frontispiece']">
  <xsl:apply-templates/>
</xsl:template>

<xsl:template match="tei:div[@type='illustration']">
  <xsl:apply-templates/>
</xsl:template>

<xsl:template match="tei:div|tei:div1|tei:div2|tei:div3|tei:div4|tei:div5|tei:div6">
  <xsl:variable name="depth">
    <xsl:apply-templates mode="depth" select="."/>
  </xsl:variable>
  <!-- depending on depth and splitting level, 
	 we may do one of two things: -->
  <xsl:choose>
    <!-- -1. Override at top level -->
    <xsl:when test="ancestor::tei:floatingText">
      <div>
        <xsl:call-template name="divClassAttribute">
          <xsl:with-param name="depth" select="$depth"/>
        </xsl:call-template>
        <xsl:call-template name="doDivBody">
          <xsl:with-param name="Depth" select="$depth"/>
        </xsl:call-template>
      </div>
    </xsl:when>
    <xsl:when test="ancestor::tei:TEI/@rend='all'">
      <div>
        <xsl:call-template name="divClassAttribute">
          <xsl:with-param name="depth" select="$depth"/>
        </xsl:call-template>
        <xsl:call-template name="doDivBody">
          <xsl:with-param name="Depth" select="$depth"/>
        </xsl:call-template>
      </div>
    </xsl:when>
    <xsl:when test="ancestor::tei:TEI/@rend='frontpage'">
      <div>
        <xsl:call-template name="divClassAttribute">
          <xsl:with-param name="depth" select="$depth"/>
        </xsl:call-template>
        <xsl:call-template name="doDivBody">
          <xsl:with-param name="Depth" select="$depth"/>
        </xsl:call-template>
      </div>
    </xsl:when>
    <!--
	  <xsl:when test="ancestor::tei:text/parent::tei:group">
	  <div>
	  <xsl:call-template name="divClassAttribute">
	  <xsl:with-param name="depth" select="$depth"/>
	  </xsl:call-template>
	  <xsl:call-template name="doDivBody">
	  <xsl:with-param name="Depth" select="$depth"/>
	  </xsl:call-template>
	  </div>
	  </xsl:when>
      -->
    <!-- 0. We have gone far enough -->
    <xsl:when test="$depth = $splitLevel and $STDOUT='true'">
      <xsl:if test="$virtualPages='true'">
        <xsl:call-template name="makeDivPage">
          <xsl:with-param name="depth" select="$depth"/>
        </xsl:call-template>
      </xsl:if>
    </xsl:when>
    <!-- 1. our section depth is below the splitting level -->
    <xsl:when test="number($depth) > number($splitLevel) or         @rend='nosplit' or ancestor::tei:TEI/@rend='all' or         ancestor::tei:TEI/@rend='frontpage' or         ancestor::tei:TEI/@rend='nosplit'">
      <div>
        <xsl:call-template name="divClassAttribute">
          <xsl:with-param name="depth" select="$depth"/>
        </xsl:call-template>
        <xsl:call-template name="doDivBody">
          <xsl:with-param name="Depth" select="$depth"/>
        </xsl:call-template>
      </div>
    </xsl:when>
    <!-- 2. we are at or above splitting level, 
	   so start a new page  -->
    <xsl:when test="number($depth) <= number($splitLevel) and ancestor::tei:front and $splitFrontmatter='true'">
      <xsl:call-template name="makeDivPage">
        <xsl:with-param name="depth" select="$depth"/>
      </xsl:call-template>
    </xsl:when>
    <xsl:when test="number($depth) <= number($splitLevel) and ancestor::tei:back and $splitBackmatter='true'">
      <xsl:call-template name="makeDivPage">
        <xsl:with-param name="depth" select="$depth"/>
      </xsl:call-template>
    </xsl:when>
    <xsl:when test="number($depth) <= number($splitLevel) and ancestor::tei:body">
      <xsl:call-template name="makeDivPage">
        <xsl:with-param name="depth" select="$depth"/>
      </xsl:call-template>
    </xsl:when>
    <xsl:otherwise>
      <div>
        <xsl:call-template name="divClassAttribute">
          <xsl:with-param name="depth" select="$depth"/>
        </xsl:call-template>
        <xsl:call-template name="doDivBody">
          <xsl:with-param name="Depth" select="$depth"/>
        </xsl:call-template>
      </div>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

<xsl:template name="makeDivPage">
  <xsl:param name="depth"/>
  <xsl:choose>
    <xsl:when test="$virtualPages='true'">
      <div>
        <xsl:call-template name="divClassAttribute">
          <xsl:with-param name="depth" select="$depth"/>
        </xsl:call-template>
        <xsl:if test="$topNavigationPanel='true'">
          <xsl:call-template name="xrefpanel">
            <xsl:with-param name="mode" select="local-name(.)"/>
          </xsl:call-template>
        </xsl:if>
        <xsl:call-template name="doDivBody">
          <xsl:with-param name="Depth" select="$depth"/>
        </xsl:call-template>
        <xsl:if test="$bottomNavigationPanel='true'">
          <xsl:call-template name="xrefpanel">
            <xsl:with-param name="mode" select="local-name(.)"/>
          </xsl:call-template>
        </xsl:if>
      </div>
    </xsl:when>
    <xsl:otherwise>
      <xsl:variable name="outName">
        <xsl:call-template name="outputChunkName">
          <xsl:with-param name="ident">
            <xsl:apply-templates mode="ident" select="."/>
          </xsl:with-param>
        </xsl:call-template>
      </xsl:variable>
      <xsl:if test="$verbose='true'">
        <xsl:message>Opening file
          <xsl:value-of select="$outName"/>
        </xsl:message>
      </xsl:if>
      <xsl:result-document doctype-public="{$doctypePublic}" doctype-system="{$doctypeSystem}" encoding="{$outputEncoding}" href="{$outName}" method="{$outputMethod}">
        <xsl:choose>
          <xsl:when test="$pageLayout='CSS'">
            <xsl:call-template name="pageLayoutCSS">
              <xsl:with-param name="currentID">
                <xsl:apply-templates mode="ident" select="."/>
              </xsl:with-param>
            </xsl:call-template>
          </xsl:when>
          <xsl:when test="$pageLayout='Table'">
            <xsl:call-template name="pageLayoutTable">
              <xsl:with-param name="currentID">
                <xsl:apply-templates mode="ident" select="."/>
              </xsl:with-param>
            </xsl:call-template>
          </xsl:when>
          <xsl:otherwise>
            <xsl:call-template name="writeDiv"/>
          </xsl:otherwise>
        </xsl:choose>
      </xsl:result-document>
      <xsl:if test="$verbose='true'">
        <xsl:message>Closing file
          <xsl:value-of select="$outName"/>
        </xsl:message>
      </xsl:if>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

<xsl:template match="tei:docAuthor" mode="author">
  <xsl:if test="preceding-sibling::tei:docAuthor">
    <xsl:text>, </xsl:text>
  </xsl:if>
  <xsl:apply-templates/>
</xsl:template>

<xsl:template match="tei:docTitle|tei:docAuthor|tei:docImprint|tei:docDate">
  <div>
    <xsl:choose>
      <xsl:when test="@rendition">
        <xsl:call-template name="applyRendition"/>
      </xsl:when>
      <xsl:otherwise>
        <xsl:attribute name="class">
          <xsl:value-of select="local-name()">
          </xsl:value-of>
        </xsl:attribute>
      </xsl:otherwise>
    </xsl:choose>
    <xsl:apply-templates/>
  </div>
</xsl:template>

<xsl:template match="tei:opener">
  <xsl:choose>
    <xsl:when test="tei:signed|tei:salute">
      <div class="opener">
        <xsl:apply-templates/>
      </div>
    </xsl:when>
    <xsl:when test="tei:p">
      <blockquote class="opener">
        <xsl:apply-templates/>
      </blockquote>
    </xsl:when>
    <xsl:otherwise>
      <blockquote class="opener">
        <p>
          <xsl:apply-templates/>
        </p>
      </blockquote>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

<xsl:template match="tei:text">
  <xsl:choose>
    <xsl:when test="parent::tei:TEI">
      <xsl:apply-templates/>
    </xsl:when>
    <xsl:when test="parent::tei:group and tei:body/tei:head     and $splitLevel=0">
      <xsl:call-template name="makeDivPage">
        <xsl:with-param name="depth">-1</xsl:with-param>
      </xsl:call-template>
    </xsl:when>
    <xsl:when test="parent::tei:group">
      <xsl:call-template name="doDivBody"/>
    </xsl:when>
    <xsl:otherwise>
      <div class="innertext">
        <xsl:apply-templates mode="innertext"/>
      </div>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

<xsl:template match="tei:titlePage">
  <div class="titlePage">
    <xsl:apply-templates/>
  </div>
</xsl:template>

<xsl:template name="aCrumb">
  <xsl:param name="crumbBody"/>
  <li class="breadcrumb">
    <xsl:copy-of select="$crumbBody"/>
  </li>
</xsl:template>

<xsl:template name="addCorpusID">
  <xsl:if test="ancestor-or-self::tei:teiCorpus">
    <xsl:for-each select="ancestor-or-self::tei:TEI">
      <xsl:text>-</xsl:text>
      <xsl:choose>
        <xsl:when test="@xml:id">
          <xsl:value-of select="@xml:id"/>
        </xsl:when>
        <xsl:otherwise>
          <xsl:number/>
        </xsl:otherwise>
      </xsl:choose>
    </xsl:for-each>
  </xsl:if>
</xsl:template>

<xsl:template name="addLangAtt">
  <xsl:variable name="documentationLanguage">
    <xsl:choose>
      <xsl:when test="string-length($doclang)>0">
        <xsl:value-of select="$doclang"/>
      </xsl:when>
      <xsl:when test="ancestor-or-self::tei:schemaSpec/@docLang">
        <xsl:value-of select="//tei:schemaSpec[1]/@docLang"/>
      </xsl:when>
      <xsl:otherwise>
        <xsl:text>en</xsl:text>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:variable>
  <xsl:variable name="supplied">
    <xsl:choose>
      <xsl:when test="ancestor-or-self::tei:*[@xml:lang]">
        <xsl:value-of select="ancestor-or-self::tei:*[@xml:lang][1]/@xml:lang"/>
      </xsl:when>
      <xsl:when test="ancestor-or-self::tei:*[@lang]">
        <xsl:value-of select="ancestor-or-self::tei:*[@lang][1]/@lang"/>
      </xsl:when>
      <xsl:otherwise>
        <xsl:value-of select="$documentationLanguage"/>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:variable>
  <xsl:attribute name="lang">
    <xsl:value-of select="$supplied"/>
  </xsl:attribute>
</xsl:template>

<xsl:template name="crumbPath">
  <xsl:param name="crumbRoot">/</xsl:param>
  <div class="breadcrumb">
    <xsl:call-template name="preBreadCrumbPath"/>
    <ul class="breadcrumb">
      <li class="breadcrumb-first">
        <a class="breadcrumb" href="{$homeURL}">
          <xsl:value-of select="$homeLabel"/>
        </a>
      </li>
      <xsl:call-template name="walkTree">
        <xsl:with-param name="path">
          <xsl:value-of select="substring-after($REQUEST,$crumbRoot)"/>
        </xsl:with-param>
        <xsl:with-param name="whole">
          <xsl:value-of select="$crumbRoot"/>
        </xsl:with-param>
        <xsl:with-param name="class">breadcrumb</xsl:with-param>
      </xsl:call-template>
    </ul>
  </div>
</xsl:template>

<xsl:template name="doDivBody">
  <xsl:param name="Depth"/>
  <xsl:call-template name="startDivHook"/>
  <xsl:variable name="ident">
    <xsl:apply-templates mode="ident" select="."/>
  </xsl:variable>
  <xsl:choose>
    <xsl:when test="parent::tei:*/@rend='multicol'">
      <td valign="top">
        <xsl:if test="not($Depth = '')">
          <xsl:element name="h{$Depth + $divOffset}">
            <xsl:for-each select="tei:head[1]">
              <xsl:call-template name="rendToClass">
                <xsl:with-param name="default"/>
              </xsl:call-template>
            </xsl:for-each>
            <xsl:call-template name="header">
              <xsl:with-param name="display">full</xsl:with-param>
            </xsl:call-template>
            <xsl:call-template name="sectionHeadHook"/>
          </xsl:element>
        </xsl:if>
        <xsl:apply-templates/>
      </td>
    </xsl:when>
    <xsl:when test="@rend='multicol'">
      <xsl:apply-templates select="*[not(local-name(.)='div')]"/>
      <table>
        <tr>
          <xsl:apply-templates select="tei:div"/>
        </tr>
      </table>
    </xsl:when>
    <xsl:when test="@rend='nohead'">
      <xsl:apply-templates/>
    </xsl:when>
    <xsl:otherwise>
      <xsl:if test="not($Depth = '')">
        <xsl:element name="h{$Depth + $divOffset}">
          <xsl:choose>
            <xsl:when test="@rend">
              <xsl:call-template name="rendToClass"/>
            </xsl:when>
            <xsl:otherwise>
              <xsl:for-each select="tei:head[1]">
                <xsl:call-template name="rendToClass">
                  <xsl:with-param name="default"/>
                </xsl:call-template>
              </xsl:for-each>
            </xsl:otherwise>
          </xsl:choose>
          <xsl:call-template name="header">
            <xsl:with-param name="display">full</xsl:with-param>
          </xsl:call-template>
          <xsl:call-template name="sectionHeadHook"/>
        </xsl:element>
      </xsl:if>
      <xsl:apply-templates/>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

<xsl:template name="doDivs">
  <xsl:for-each select="tei:TEI/tei:text">
    <xsl:for-each select="tei:front|tei:body|tei:back">
      <xsl:for-each select="tei:div|tei:div1">
        <xsl:variable name="currentID">
          <xsl:apply-templates mode="ident" select="."/>
        </xsl:variable>
        <xsl:call-template name="doPageTable">
          <xsl:with-param name="currentID" select="$currentID"/>
        </xsl:call-template>
      </xsl:for-each>
    </xsl:for-each>
  </xsl:for-each>
</xsl:template>

<xsl:template name="doFrames">
  <xsl:variable name="BaseFile">
    <xsl:value-of select="$masterFile"/>
    <xsl:call-template name="addCorpusID"/>
  </xsl:variable>
  <xsl:choose>
    <xsl:when test="$requestedID='toclist___'">
      <xsl:call-template name="writeFrameToc"/>
    </xsl:when>
    <xsl:when test="$STDOUT='true'">
      <xsl:call-template name="pageLayoutSimple"/>
    </xsl:when>
    <xsl:otherwise>
      <xsl:variable name="outName">
        <xsl:call-template name="outputChunkName">
          <xsl:with-param name="ident">
            <xsl:value-of select="concat($BaseFile,'-menubar')"/>
          </xsl:with-param>
        </xsl:call-template>
      </xsl:variable>
      <xsl:if test="$verbose='true'">
        <xsl:message>Opening file
          <xsl:value-of select="$outName"/>
        </xsl:message>
      </xsl:if>
      <xsl:result-document doctype-public="{$doctypePublic}" doctype-system="{$doctypeSystem}" encoding="{$outputEncoding}" href="{$outName}" method="{$outputMethod}">
        <xsl:call-template name="writeFrameToc"/>
      </xsl:result-document>
      <xsl:if test="$verbose='true'">
        <xsl:message>Closing file
          <xsl:value-of select="$outName"/>
        </xsl:message>
      </xsl:if>
      <xsl:variable name="outName2">
        <xsl:call-template name="outputChunkName">
          <xsl:with-param name="ident">
            <xsl:value-of select="concat($BaseFile,'-frames')"/>
          </xsl:with-param>
        </xsl:call-template>
      </xsl:variable>
      <xsl:if test="$verbose='true'">
        <xsl:message>Opening file
          <xsl:value-of select="$outName2"/>
        </xsl:message>
      </xsl:if>
      <xsl:result-document doctype-public="{$doctypePublic}" doctype-system="{$doctypeSystem}" encoding="{$outputEncoding}" href="{$outName2}" method="{$outputMethod}">
        <xsl:call-template name="pageLayoutSimple"/>
      </xsl:result-document>
      <xsl:if test="$verbose='true'">
        <xsl:message>Closing file
          <xsl:value-of select="$outName"/>
        </xsl:message>
      </xsl:if>
      <xsl:apply-templates mode="split" select="tei:TEI"/>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

<xsl:template name="doPageTable">
  <xsl:param name="currentID"/>
  <xsl:variable name="BaseFile">
    <xsl:value-of select="$masterFile"/>
    <xsl:call-template name="addCorpusID"/>
  </xsl:variable>
  <xsl:choose>
    <xsl:when test="$STDOUT='true'">
      <xsl:choose>
        <xsl:when test="$pageLayout='CSS'">
          <xsl:call-template name="pageLayoutCSS">
            <xsl:with-param name="currentID" select="$currentID"/>
          </xsl:call-template>
        </xsl:when>
        <xsl:when test="$pageLayout='Table'">
          <xsl:call-template name="pageLayoutTable">
            <xsl:with-param name="currentID" select="$currentID"/>
          </xsl:call-template>
        </xsl:when>
      </xsl:choose>
    </xsl:when>
    <xsl:otherwise>
      <xsl:variable name="outName">
        <xsl:call-template name="outputChunkName">
          <xsl:with-param name="ident">
            <xsl:choose>
              <xsl:when test="not($currentID='')">
                <xsl:value-of select="$currentID"/>
              </xsl:when>
              <xsl:otherwise>
                <xsl:value-of select="$BaseFile"/>
              </xsl:otherwise>
            </xsl:choose>
          </xsl:with-param>
        </xsl:call-template>
      </xsl:variable>
      <xsl:if test="$verbose='true'">
        <xsl:message>Opening file
          <xsl:value-of select="$outName"/>
        </xsl:message>
      </xsl:if>
      <xsl:result-document doctype-public="{$doctypePublic}" doctype-system="{$doctypeSystem}" encoding="{$outputEncoding}" href="{$outName}" method="{$outputMethod}">
        <xsl:choose>
          <xsl:when test="$pageLayout='CSS'">
            <xsl:call-template name="pageLayoutCSS">
              <xsl:with-param name="currentID" select="$currentID"/>
            </xsl:call-template>
          </xsl:when>
          <xsl:when test="$pageLayout='Table'">
            <xsl:call-template name="pageLayoutTable">
              <xsl:with-param name="currentID" select="$currentID"/>
            </xsl:call-template>
          </xsl:when>
        </xsl:choose>
      </xsl:result-document>
      <xsl:if test="$verbose='true'">
        <xsl:message>Closing file
          <xsl:value-of select="$outName"/>
        </xsl:message>
      </xsl:if>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

<xsl:template name="generateDivtitle">
  <xsl:apply-templates select="tei:head/text()"/>
</xsl:template>

<xsl:template name="generateUpLink">
  <xsl:variable name="myName">
    <xsl:value-of select="local-name(.)"/>
  </xsl:variable>
  <xsl:variable name="BaseFile">
    <xsl:value-of select="$masterFile"/>
    <xsl:value-of select="$standardSuffix"/>
    <xsl:call-template name="addCorpusID"/>
  </xsl:variable>
  <xsl:choose>
    <xsl:when test="$myName = 'div' and not(ancestor::tei:div)">
      <xsl:call-template name="upLink">
        <xsl:with-param name="up" select="$BaseFile"/>
        <xsl:with-param name="title" select="$homeLabel"/>
      </xsl:call-template>
    </xsl:when>
    <xsl:when test="$myName = 'div'">
      <xsl:call-template name="upLink">
        <xsl:with-param name="up" select="ancestor::tei:div[1]"/>
      </xsl:call-template>
    </xsl:when>
    <xsl:when test="$myName='div1'">
      <xsl:call-template name="upLink">
        <xsl:with-param name="up" select="$BaseFile"/>
        <xsl:with-param name="title" select="$homeLabel"/>
      </xsl:call-template>
    </xsl:when>
    <xsl:when test="$myName='div2'">
      <xsl:call-template name="upLink">
        <xsl:with-param name="up" select="ancestor::tei:div1"/>
      </xsl:call-template>
    </xsl:when>
    <xsl:when test="$myName='div3'">
      <xsl:call-template name="upLink">
        <xsl:with-param name="up" select="ancestor::tei:div2"/>
      </xsl:call-template>
    </xsl:when>
    <xsl:when test="$myName='div4'">
      <xsl:call-template name="upLink">
        <xsl:with-param name="up" select="ancestor::tei:div3"/>
      </xsl:call-template>
    </xsl:when>
    <xsl:when test="$myName='div5'">
      <xsl:call-template name="upLink">
        <xsl:with-param name="up" select="ancestor::tei:div4"/>
      </xsl:call-template>
    </xsl:when>
    <xsl:otherwise>
      <xsl:call-template name="upLink">
        <xsl:with-param name="up" select="(ancestor::tei:div1|ancestor::tei:div)[1]"/>
      </xsl:call-template>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

<xsl:template name="htmlFileBottom">
  <xsl:call-template name="topNavigation"/>
  <xsl:call-template name="stdfooter"/>
</xsl:template>

<xsl:template name="htmlFileTop">
  <xsl:comment>THIS FILE IS GENERATED FROM AN XML MASTER. DO NOT EDIT (6)</xsl:comment>
  <xsl:variable name="pagetitle">
    <xsl:call-template name="generateTitle"/>
  </xsl:variable>
  <head>
    <title>
      <xsl:value-of select="$pagetitle"/>
    </title>
    <xsl:call-template name="headHook"/>
    <xsl:call-template name="metaHTML">
      <xsl:with-param name="title" select="$pagetitle"/>
    </xsl:call-template>
    <xsl:call-template name="includeCSS"/>
    <xsl:call-template name="cssHook"/>
    <xsl:call-template name="includeJavascript"/>
    <xsl:call-template name="javascriptHook"/>
  </head>
</xsl:template>

<xsl:template name="includeCSS">
  <xsl:choose>
    <xsl:when test="$cssFile = ''"/>
    <xsl:otherwise>
      <link href="{$cssFile}" rel="stylesheet" type="text/css"/>
    </xsl:otherwise>
  </xsl:choose>
  <xsl:if test="not($cssSecondaryFile='')">
    <link href="{$cssSecondaryFile}" rel="stylesheet" type="text/css"/>
  </xsl:if>
  <xsl:if test="not($cssPrintFile='')">
    <link rel="stylesheet" media="print" type="text/css" href="{$cssPrintFile}"/>
  </xsl:if>
  <xsl:call-template name="generateLocalCSS"/>
</xsl:template>

<xsl:template name="includeJavascript">
</xsl:template>

<xsl:template name="writeJavascript">
  <xsl:param name="content"/>
  <script type="text/javascript">
    <xsl:value-of select="$content"/>
  </script>
</xsl:template>

<xsl:template name="leftHandFrame">
  <xsl:param name="currentID"/>
  <xsl:call-template name="makeSidebar"/>
  <xsl:choose>
    <xsl:when test="$currentID=''">
      <xsl:call-template name="linkListContents">
        <xsl:with-param name="style" select="'toclist'"/>
      </xsl:call-template>
    </xsl:when>
    <xsl:otherwise>
      <xsl:choose>
        <xsl:when test="count(key('IDS',$currentID))>0">
          <xsl:for-each select="key('IDS',$currentID)">
            <xsl:call-template name="linkListContents">
              <xsl:with-param name="style" select="'toclist'"/>
            </xsl:call-template>
          </xsl:for-each>
        </xsl:when>
        <xsl:otherwise>
          <xsl:apply-templates mode="xpath" select="ancestor-or-self::tei:TEI/tei:text">
            <xsl:with-param name="xpath" select="$currentID"/>
            <xsl:with-param name="action" select="'toclist'"/>
          </xsl:apply-templates>
        </xsl:otherwise>
      </xsl:choose>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

<xsl:template match="tei:list[@type='sidebar']"/>

<xsl:template name="makeSidebar">
  <xsl:for-each select="ancestor-or-self::tei:TEI/tei:text/tei:body/tei:list[@type='sidebar']">
    <xsl:for-each select=".//tei:ref">
      <p class="sidebar">
        <a class="toclist" href="{@url}">
          <xsl:apply-templates/>
        </a>
      </p>
    </xsl:for-each>
    <hr/>
  </xsl:for-each>
</xsl:template>

<xsl:template name="linkListContents">
  <xsl:param name="style" select="'toc'"/>
  <xsl:variable name="BaseFile">
    <xsl:value-of select="$masterFile"/>
    <xsl:call-template name="addCorpusID"/>
  </xsl:variable>
  <xsl:variable name="thisOne">
    <xsl:value-of select="generate-id()"/>
  </xsl:variable>
  <xsl:for-each select="ancestor-or-self::tei:TEI/tei:text">
    <!-- front matter -->
    <xsl:for-each select="tei:front">
      <xsl:if test="tei:div1|tei:div">
        <div class="tocFront">
          <xsl:element name="{$tocContainerElement}">
            <xsl:attribute name="class">
              <xsl:text>tocContainer</xsl:text>
            </xsl:attribute>
            <xsl:call-template name="tocSection">
              <xsl:with-param name="id" select="$thisOne"/>
              <xsl:with-param name="style" select="$style"/>
              <xsl:with-param name="force" select="$virtualPages"/>
            </xsl:call-template>
          </xsl:element>
        </div>
      </xsl:if>
    </xsl:for-each>
    <!-- body matter -->
    <xsl:for-each select="tei:body">
      <xsl:if test="tei:div1|tei:div">
        <div class="tocBody">
          <xsl:comment>start TOC</xsl:comment>
          <xsl:element name="{$tocContainerElement}">
            <xsl:attribute name="class">
              <xsl:text>tocContainer</xsl:text>
            </xsl:attribute>
            <xsl:comment>TOC components</xsl:comment>
            <xsl:call-template name="tocSection">
              <xsl:with-param name="id" select="$thisOne"/>
              <xsl:with-param name="style" select="$style"/>
              <xsl:with-param name="force" select="$virtualPages"/>
            </xsl:call-template>
          </xsl:element>
        </div>
      </xsl:if>
    </xsl:for-each>
    <!-- back matter -->
    <xsl:for-each select="tei:back">
      <xsl:if test="tei:div1|tei:div">
        <div class="tocBack">
          <xsl:element name="{$tocContainerElement}">
            <xsl:attribute name="class">
              <xsl:text>tocContainer</xsl:text>
            </xsl:attribute>
            <xsl:call-template name="tocSection">
              <xsl:with-param name="id" select="$thisOne"/>
              <xsl:with-param name="style" select="$style"/>
              <xsl:with-param name="force" select="$virtualPages"/>
            </xsl:call-template>
          </xsl:element>
        </div>
      </xsl:if>
    </xsl:for-each>
  </xsl:for-each>
</xsl:template>