<xsl:template name="write-docxfile-docprops-core">
  <xsl:variable name="now" select="teidocx:whatsTheDate()"/>
  <xsl:variable name="coreFile">
    <xsl:value-of select="$word-directory"/>
    <xsl:text>/docProps/core.xml</xsl:text>
  </xsl:variable>
  <xsl:variable name="createdDate">
    <xsl:choose>
      <xsl:when test="doc-available($coreFile)">
        <xsl:for-each select="document($coreFile)">
          <xsl:value-of select="cp:coreProperties/dcterms:created"/>
        </xsl:for-each>
      </xsl:when>
      <xsl:otherwise>
        <xsl:value-of select="$now"/>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:variable>
  <xsl:variable name="revision">
    <xsl:choose>
      <xsl:when test="doc-available($coreFile)">
        <xsl:for-each select="document($coreFile)">
          <xsl:value-of select="cp:coreProperties/cp:revision + 1"/>
        </xsl:for-each>
      </xsl:when>
      <xsl:otherwise>1</xsl:otherwise>
    </xsl:choose>
  </xsl:variable>
  <!-- after opening core.xml, we cannot write back to it; so save
            under new name -->
  <xsl:if test="$debug='true'">
    <xsl:message>Writing out
      <xsl:value-of select="concat($word-directory,'/docProps/newcore.xml')"/>
    </xsl:message>
  </xsl:if>
  <xsl:result-document href="{concat($word-directory,'/docProps/newcore.xml')}" standalone="yes">
    <cp:coreProperties>
      <dc:title>
        <xsl:call-template name="generateTitle"/>
      </dc:title>
      <dc:creator>
        <xsl:call-template name="created-by"/>
      </dc:creator>
      <cp:lastModifiedBy>TEIISO</cp:lastModifiedBy>
      <cp:revision>
        <xsl:value-of select="$revision"/>
      </cp:revision>
      <dcterms:created xsi:type="dcterms:W3CDTF">
        <xsl:value-of select="$createdDate"/>
      </dcterms:created>
      <dcterms:modified xsi:type="dcterms:W3CDTF">
        <xsl:value-of select="$now"/>
      </dcterms:modified>
    </cp:coreProperties>
  </xsl:result-document>
</xsl:template>

<xsl:template name="write-docxfile-docprops-app">
  <xsl:if test="$debug='true'">
    <xsl:message>Writing out
      <xsl:value-of select="concat($word-directory,'/docProps/app.xml')"/>
    </xsl:message>
  </xsl:if>
  <xsl:result-document href="{concat($word-directory,'/docProps/app.xml')}" standalone="yes">
    <Properties xmlns="http://schemas.openxmlformats.org/officeDocument/2006/extended-properties" xmlns:vt="http://schemas.openxmlformats.org/officeDocument/2006/docPropsVTypes">
      <Template>STD_3_0_0.dotx</Template>
      <Application>TEIISO tei-docx.xsl</Application>
      <DocSecurity>0</DocSecurity>
      <SharedDoc>true</SharedDoc>
      <AppVersion>1.0</AppVersion>
    </Properties>
  </xsl:result-document>
</xsl:template>

<xsl:template name="write-docxfile-docprops-custom">
  <xsl:if test="$debug='true'">
    <xsl:message>Writing out
      <xsl:value-of select="concat($word-directory,'/docProps/newcustom.xml')"/>
    </xsl:message>
  </xsl:if>
  <xsl:result-document href="{concat($word-directory,'/docProps/newcustom.xml')}" standalone="yes">
    <Properties xmlns="http://schemas.openxmlformats.org/officeDocument/2006/custom-properties" xmlns:vt="http://schemas.openxmlformats.org/officeDocument/2006/docPropsVTypes">
      <property pid="1001" name="TEI_toDOCX">
        <xsl:attribute name="fmtid">
          <xsl:text>{D5CDD505-2E9C-101B-9397-08002B2CF9AE}</xsl:text>
        </xsl:attribute>
        <vt:lpwstr>2.15.0</vt:lpwstr>
      </property>
      <xsl:for-each select="ancestor-or-self::tei:TEI/tei:teiHeader/tei:encodingDesc/tei:appInfo/tei:application">
        <xsl:if test="not(@ident='TEI_toDOCX')">
          <property name="{@ident}">
            <xsl:attribute name="pid">
              <xsl:value-of select="position()+1001"/>
            </xsl:attribute>
            <xsl:attribute name="fmtid">
              <xsl:text>{D5CDD505-2E9C-101B-9397-08002B2CF9AE}</xsl:text>
            </xsl:attribute>
            <vt:lpwstr>
              <xsl:value-of select="@version"/>
            </vt:lpwstr>
          </property>
        </xsl:if>
      </xsl:for-each>
    </Properties>
  </xsl:result-document>
</xsl:template>