Stylesheet documentation for:

Description

TEI stylesheet dealing with elements from the linking module.

This software is dual-licensed: 1. Distributed under a Creative Commons Attribution-ShareAlike 3.0 Unported License http://creativecommons.org/licenses/by-sa/3.0/ 2. http://www.opensource.org/licenses/BSD-2-Clause All rights reserved. Redistribution and use in source and binary forms, with or without modification, are permitted provided that the following conditions are met: * Redistributions of source code must retain the above copyright notice, this list of conditions and the following disclaimer. * Redistributions in binary form must reproduce the above copyright notice, this list of conditions and the following disclaimer in the documentation and/or other materials provided with the distribution. This software is provided by the copyright holders and contributors "as is" and any express or implied warranties, including, but not limited to, the implied warranties of merchantability and fitness for a particular purpose are disclaimed. In no event shall the copyright holder or contributors be liable for any direct, indirect, incidental, special, exemplary, or consequential damages (including, but not limited to, procurement of substitute goods or services; loss of use, data, or profits; or business interruption) however caused and on any theory of liability, whether in contract, strict liability, or tort (including negligence or otherwise) arising in any way out of the use of this software, even if advised of the possibility of such damage.

Author: See AUTHORS

Id: $Id: linking.xsl 10642 2012-07-03 22:01:32Z rahtz $

Description

Process element in xref mode

<xsl:template match="tei:TEI" mode="xref">
  <xsl:apply-templates select="tei:teiHeader/tei:fileDesc/tei:titleStmt/tei:title[1]"/>
</xsl:template>

Description

Process elements text in xref mode

<xsl:template match="tei:text" mode="xref">
  <xsl:choose>
    <xsl:when test="tei:head">
      <xsl:apply-templates select="tei:head" mode="plain"/>
    </xsl:when>
    <xsl:when test="tei:body/tei:head">
      <xsl:apply-templates select="tei:body/tei:head" mode="plain"/>
    </xsl:when>
    <xsl:when test="tei:front//tei:titlePart/tei:title">
      <xsl:apply-templates select="tei:front//tei:titlePart/tei:titl" mode="plain"/>
    </xsl:when>
    <xsl:otherwise>
      <xsl:text>Text </xsl:text>
      <xsl:number/>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

Description

Process element anchor|tei:p in xref mode

<xsl:template match="tei:anchor|tei:p" mode="xref">
  <xsl:text>here</xsl:text>
</xsl:template>

Description

Process element bibl

<xsl:template match="tei:bibl" mode="xref">
  <xsl:text>[</xsl:text>
  <xsl:number/>
  <xsl:text>]</xsl:text>
</xsl:template>

Description

Parameters

QName	Namespace
minimal	No namespace

<xsl:template match="tei:div|tei:div1|tei:div2|tei:div3|tei:div4|tei:div5|tei:div6" mode="xref">
  <xsl:param name="minimal">false</xsl:param>
  <xsl:call-template name="header">
    <xsl:with-param name="minimal" select="$minimal"/>
    <xsl:with-param name="display">plain</xsl:with-param>
  </xsl:call-template>
</xsl:template>

Description

Process element ptr in xref mode

Template

makeTEILink

<xsl:template match="tei:ptr">
  <xsl:call-template name="makeTEILink">
    <xsl:with-param name="ptr" select="true()"/>
  </xsl:call-template>
</xsl:template>

Description

Process element ref

Template

makeTEILink

<xsl:template match="tei:ref">
  <xsl:call-template name="makeTEILink">
    <xsl:with-param name="ptr" select="false()"/>
  </xsl:call-template>
</xsl:template>

Description

[common] Making a heading for something

Parameters

QName	Namespace
display	No namespace
minimal	No namespace
toc	No namespace

<xsl:template name="header">
  <xsl:param name="minimal">false</xsl:param>
  <xsl:param name="toc"/>
  <xsl:param name="display">full</xsl:param>
  <xsl:variable name="depth">
    <xsl:apply-templates mode="depth" select="."/>
  </xsl:variable>
  <xsl:call-template name="formatHeadingNumber">
    <xsl:with-param name="toc">
      <xsl:value-of select="$toc"/>
    </xsl:with-param>
    <xsl:with-param name="text">
      <xsl:choose>
        <xsl:when test="local-name(.) = 'TEI'">
          <xsl:if test="@n">
            <xsl:value-of select="@n"/>
          </xsl:if>
        </xsl:when>
        <xsl:when test="$depth > $numberHeadingsDepth">
        </xsl:when>
        <xsl:when test="self::tei:text">
          <xsl:number/>
          <xsl:call-template name="headingNumberSuffix"/>
        </xsl:when>
        <xsl:when test="ancestor::tei:back">
          <xsl:if test="$numberBackHeadings='true'">
            <xsl:call-template name="i18n">
              <xsl:with-param name="word">appendixWords</xsl:with-param>
            </xsl:call-template>
            <xsl:text> </xsl:text>
            <xsl:call-template name="numberBackDiv"/>
            <xsl:if test="$minimal='false'">
              <xsl:value-of select="$numberSpacer"/>
            </xsl:if>
          </xsl:if>
        </xsl:when>
        <xsl:when test="ancestor::tei:front">
          <xsl:if test="$numberFrontHeadings='true'">
            <xsl:call-template name="numberFrontDiv">
              <xsl:with-param name="minimal">
                <xsl:value-of select="$minimal"/>
              </xsl:with-param>
            </xsl:call-template>
          </xsl:if>
        </xsl:when>
        <xsl:when test="$numberHeadings ='true'">
          <xsl:choose>
            <xsl:when test="$prenumberedHeadings='true'">
              <xsl:value-of select="@n"/>
            </xsl:when>
            <xsl:otherwise>
              <xsl:call-template name="numberBodyDiv"/>
            </xsl:otherwise>
          </xsl:choose>
          <xsl:if test="$minimal='false'">
            <xsl:call-template name="headingNumberSuffix"/>
          </xsl:if>
        </xsl:when>
      </xsl:choose>
    </xsl:with-param>
  </xsl:call-template>
  <xsl:if test="$minimal='false'">
    <xsl:choose>
      <xsl:when test="local-name(.) = 'TEI'">
        <xsl:apply-templates select="tei:teiHeader/tei:fileDesc/tei:titleStmt/tei:title[1]"/>
      </xsl:when>
      <xsl:when test="not($toc='')">
        <xsl:call-template name="makeInternalLink">
          <xsl:with-param name="dest">
            <xsl:value-of select="$toc"/>
          </xsl:with-param>
          <xsl:with-param name="class">
            <xsl:value-of select="$class_toc"/>
            <xsl:text> </xsl:text>
            <xsl:value-of select="concat($class_toc,'_',$depth)"/>
          </xsl:with-param>
          <xsl:with-param name="body">
            <xsl:choose>
              <xsl:when test="not(tei:head) and tei:body/tei:head">
                <xsl:apply-templates mode="plain" select="tei:body/tei:head"/>
              </xsl:when>
              <xsl:when test="not(tei:head) and tei:front//tei:titlePart/tei:title">
                <xsl:apply-templates mode="plain" select="tei:front//tei:titlePart/tei:title"/>
              </xsl:when>
              <xsl:when test="tei:head">
                <xsl:apply-templates mode="plain" select="tei:head"/>
              </xsl:when>
              <xsl:when test="$autoHead='true'">
                <xsl:call-template name="autoMakeHead">
                  <xsl:with-param name="display" select="$display"/>
                </xsl:call-template>
              </xsl:when>
              <xsl:otherwise>
                <xsl:number/>
              </xsl:otherwise>
            </xsl:choose>
          </xsl:with-param>
        </xsl:call-template>
      </xsl:when>
      <xsl:when test="$autoHead='true'">
        <xsl:choose>
          <xsl:when test="($outputTarget='epub' or $outputTarget='epub3') and     not(tei:head)"/>
          <xsl:otherwise>
            <xsl:call-template name="autoMakeHead">
              <xsl:with-param name="display" select="$display"/>
            </xsl:call-template>
          </xsl:otherwise>
        </xsl:choose>
      </xsl:when>
      <xsl:when test="$display='plain'">
        <xsl:for-each select="tei:head">
          <xsl:apply-templates mode="plain"/>
        </xsl:for-each>
      </xsl:when>
      <xsl:when test="$display='simple'">
        <xsl:for-each select="tei:head">
          <xsl:apply-templates mode="plain"/>
        </xsl:for-each>
      </xsl:when>
      <xsl:when test="self::tei:index">
        <xsl:value-of select="substring(tei:term,1,10)"/>
        <xsl:text>…</xsl:text>
      </xsl:when>
      <xsl:when test="not(tei:head)">
        <xsl:value-of select="substring(normalize-space(.),1,10)"/>
        <xsl:text>…</xsl:text>
      </xsl:when>
      <xsl:otherwise>
        <xsl:apply-templates select="tei:head" mode="makeheading"/>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:if>
</xsl:template>

Description

[common] processing the number portion of a heading

By default, the text is printed as is. You may wish to colour it, align it, etc

Parameters

QName	Namespace
text	No namespace
toc	No namespace

<xsl:template name="formatHeadingNumber">
  <xsl:param name="text"/>
  <xsl:param name="toc"/>
  <xsl:copy-of select="$text"/>
</xsl:template>

Description

[common] Making a heading for something, and making sure it has contents

This is a wrapper around the "header" template which ensures that some text is returned; if all else fails, the element name is used.

Parameters

Template	header
Parameter	minimalCrossRef

QName	Namespace
minimal	No namespace

<xsl:template name="headerLink">
  <xsl:param name="minimal">false</xsl:param>
  <xsl:variable name="Text">
    <xsl:call-template name="header">
      <xsl:with-param name="minimal" select="$minimalCrossRef"/>
      <xsl:with-param name="display">plain</xsl:with-param>
    </xsl:call-template>
  </xsl:variable>
  <xsl:choose>
    <xsl:when test="$Text=''">
      <!--
	       <xsl:text>&lt;</xsl:text>
	       <xsl:value-of select="local-name(.)"/>
	       <xsl:text>&gt;</xsl:text>
	   -->
    </xsl:when>
    <xsl:otherwise>
      <xsl:copy-of select="$Text"/>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

Description

[common] Make a hypertext link

cross-referencing

Parameters

Templates

tei:ptr;

tei:ref

QName	Namespace	Select	Type
ptr	No namespace	false()	xs:boolean

<xsl:template name="makeTEILink">
  <xsl:param name="ptr" as="xs:boolean" select="false()"/>
  <!-- is this a ptr or a ref? -->
  <xsl:choose>
    <!-- If there is a target attribute starting with #, it is always a local reference -->
    <xsl:when test="@target and starts-with(@target,'#')">
      <xsl:call-template name="makeInternalLink">
        <xsl:with-param name="target" select="substring(@target,2)"/>
        <xsl:with-param name="ptr" select="$ptr"/>
        <xsl:with-param name="dest">
          <xsl:call-template name="generateEndLink">
            <xsl:with-param name="where">
              <xsl:value-of select="substring(@target,2)"/>
            </xsl:with-param>
          </xsl:call-template>
        </xsl:with-param>
      </xsl:call-template>
    </xsl:when>
    <!-- if we are doing TEI P4, all targets are local -->
    <xsl:when test="@target and $teiP4Compat='true'">
      <xsl:call-template name="makeInternalLink">
        <xsl:with-param name="target" select="@target"/>
        <xsl:with-param name="ptr" select="$ptr"/>
        <xsl:with-param name="dest">
          <xsl:call-template name="generateEndLink">
            <xsl:with-param name="where">
              <xsl:value-of select="@target"/>
            </xsl:with-param>
          </xsl:call-template>
        </xsl:with-param>
      </xsl:call-template>
    </xsl:when>
    <!-- other uses of target means it is external -->
    <xsl:when test="@target">
      <xsl:call-template name="makeExternalLink">
        <xsl:with-param name="ptr" select="$ptr"/>
        <xsl:with-param name="dest">
          <xsl:value-of select="@target"/>
        </xsl:with-param>
      </xsl:call-template>
    </xsl:when>
    <!-- If there is a url attribute starting with #, it is a local
       reference -->
    <xsl:when test="@url and starts-with(@url,'#')">
      <xsl:call-template name="makeInternalLink">
        <xsl:with-param name="target" select="substring(@url,2)"/>
        <xsl:with-param name="ptr" select="$ptr"/>
        <xsl:with-param name="dest">
          <xsl:call-template name="generateEndLink">
            <xsl:with-param name="where">
              <xsl:value-of select="substring(@url,2)"/>
            </xsl:with-param>
          </xsl:call-template>
        </xsl:with-param>
      </xsl:call-template>
    </xsl:when>
    <!-- otherwise it is an external URL -->
    <xsl:when test="@url">
      <xsl:call-template name="makeExternalLink">
        <xsl:with-param name="ptr" select="$ptr"/>
        <xsl:with-param name="dest">
          <xsl:value-of select="@url"/>
        </xsl:with-param>
      </xsl:call-template>
    </xsl:when>
    <!-- A doc attribute means an external reference -->
    <xsl:when test="@doc">
      <xsl:call-template name="makeExternalLink">
        <xsl:with-param name="ptr" select="$ptr"/>
        <xsl:with-param name="dest">
          <xsl:value-of select="unparsed-entity-uri(@doc)"/>
        </xsl:with-param>
      </xsl:call-template>
    </xsl:when>
    <xsl:otherwise>
      <!--
      <xsl:for-each select="@*">
	[[markup error: <xsl:value-of select="name(.)"/>=<xsl:value-of select="."/>]]
      </xsl:for-each>
-->
      <xsl:apply-templates/>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

Stylesheet documentation generated by <oXygen/>^® XML Editor.

Mode:

Showing:

Description

Description

Description

Description

Description

Description

Parameters

Description

Description

Description

Parameters

Description

Parameters

Description

Parameters

Description

Parameters